Afficher la clé de produit Windows à l'aide d'un script

Communiquez et partagez vos astuces sur Windows 7

Afficher la clé de produit Windows à l'aide d'un script

Messagepar PatriciaG » Sam 4 Nov 2017 05:48

Il existe de nombreux logiciels pour extraire la clé de produit Windows.
De plus, le petit VBScript suivant vous permet d'obtenir la clé de produit de votre installation Windows actuelle sans utiliser un programme tiers.

Ce script fonctionne sur Windows 7, 8, 8.1 et Windows 10.

Afficher la clé de produit Windows à l'aide d'un script

Copiez le code suivant dans le Bloc-notes et enregistrez le fichier en tant que GetProductKey.vbs.

Code: Tout sélectionner
Option Explicit 
 
Dim objshell,path,DigitalID, Result 
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID) 
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
'Show messbox if save to a file 
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
   Save ProductData 
End If
 
 
 
'Convert binary to chars
Function ConvertToKey(Key)
    Const KeyOffset = 52
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
    'Check if OS is Windows 8
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Maps = "BCDFGHJKMPQRTVWXY2346789"
    Do
           Current= 0
        j = 14
        Do
           Current = Current* 256
           Current = Key(j + KeyOffset) + Current
           Key(j + KeyOffset) = (Current \ 24)
           Current=Current Mod 24
            j = j -1
        Loop While j >= 0
        i = i -1
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
        Last = Current
    Loop While i >= 0 
     
    If (isWin8 = 1) Then
        keypart1 = Mid(KeyOutput, 2, Last)
        insert = "N"
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
        If Last = 0 Then KeyOutput = insert & KeyOutput
    End If     
     
 
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
   
     
End Function
'Save data to a file
Function Save(Data)
    Dim fso, fName, txt,objshell,UserName
    Set objshell = CreateObject("wscript.shell")
    'Get current user name 
    UserName = objshell.ExpandEnvironmentStrings("%UserName%") 
    'Create a text file on desktop 
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set txt = fso.CreateTextFile(fName)
    txt.Writeline Data
    txt.Close
End Function


Double-cliquez pour exécuter le script pour trouver la clé de produit de votre système Windows.

Windows Key.png
Windows Key.png (26.25 Kio) Vu 1193 fois

Source (en anglais) : http://www.winhelponline.com/blog/view-your-product-key-windows-10-8-7-script/
Avatar de l’utilisateur
PatriciaG
 
Messages: 2808
Inscription: Jeu 11 Nov 2010 17:11
Localisation: Port-sur-Saône / Haute-Saône / France

Re: Afficher la clé de produit Windows à l'aide d'un script

Messagepar txuku » Sam 4 Nov 2017 11:37

Bonjour

Merci a toi PatriciaG pour ce script VBS qui fonctionne bien ! :)


J ai eu un petit probleme pour retrouver le fichier cree : il s est cree sur le bureau de mon disque consacre a Win10 ??? :shock:


Plus precisemment ICI : F:\Users\moi\Recent
Avatar de l’utilisateur
txuku
 
Messages: 1136
Inscription: Lun 1 Fév 2010 13:41
Localisation: Bayonne 64

Re: Afficher la clé de produit Windows à l'aide d'un script

Messagepar PatriciaG » Sam 4 Nov 2017 11:58

Bonjour,

Merci pour le retour.
Je n'ai pas de dual boot, et je suis sous W10 sur ce pc.
Si elle ne te convient pas, tu peux modifier la destination en changeant la fin du script.
Avatar de l’utilisateur
PatriciaG
 
Messages: 2808
Inscription: Jeu 11 Nov 2010 17:11
Localisation: Port-sur-Saône / Haute-Saône / France

Re: Afficher la clé de produit Windows à l'aide d'un script

Messagepar txuku » Sam 4 Nov 2017 12:20

Je n ai pas non plus de dual boot - j utilise la touche F8 au_ demarrage !

Je trouve quand meme cela etrange car ton chemin est bien ecrit ???
Avatar de l’utilisateur
txuku
 
Messages: 1136
Inscription: Lun 1 Fév 2010 13:41
Localisation: Bayonne 64

Re: Afficher la clé de produit Windows à l'aide d'un script

Messagepar PatriciaG » Sam 4 Nov 2017 12:26

Re,

Lis le tutoriel, je n'ai rien inventé.
Le script vient de là
https://gist.github.com/craigtp/dda7d0fce891a087a962d29be960f1da
Avatar de l’utilisateur
PatriciaG
 
Messages: 2808
Inscription: Jeu 11 Nov 2010 17:11
Localisation: Port-sur-Saône / Haute-Saône / France


Retourner vers Tutoriels et astuces Windows 7

Qui est en ligne

Utilisateurs parcourant ce forum: Aucun utilisateur enregistré et 1 invité

Livre photo